TechTip

Membuat PDF dan Word

Di Stata kita bisa langsung membuat dokumen dalam bentuk PDF, Word ataupun HTML ketika dibutuhkan dengan command tertentu. Di sini saya akan membahas untuk pembuatan PDF dan Word saja.

CommandKegunaan
putpdfMembuat dokumen PDF (*.pdf)
putdocxMembuat dokumen Word (*docx)
dyndocMembuat HTML dari Markdown

Membuat dokumen PDF

Dengan command putpdf  kita bisa membuat dokumen PDF dengan paragrah, tabel, hasil (output) dari Stata baik dalam paragraf, tabel maupun grafik.  

Berikut command yang diperlukan:

putpdf begin [ ,document_options]

->  untuk memulai membuat dokumen 

putpdf paragraph [, paragraph_options ] 

-> menambahkan paragraf ke dokumen

putpdf text ( text or exp ) [, text_option]

-> menambahkan text (tulisan)

putpdf image  filename [, image_option] 

-> menambahkan gambar

putpdf table tablename  

-> untuk menambahkan tabel

putpdf pagebreak 

-> untuk menambahkan pagebreak

putpdf save filename [,replace] 

-> untuk membuat dan menyimpan dokumen

 

Contoh:

Pada bagian command atau bisa juga di buat do-files yangberisi:

sysuse auto, replace
putpdf begin


// membuat paragraf

putpdf paragraph
putpdf text ("Mencoba membuat putpdf "), bold
putpdf text ("  enter"), linebreak
putpdf text ("Bisa menambahkan tulisan sesuai kebutuhan. Bisa membuat tulisan ")
putpdf text ("miring, "), italic
putpdf text (" dicoret, "), strikeout
putpdf text ("digaris bawahi"), underline
putpdf text (", sub/super script")
putpdf text ("2 "), script(sub)
putpdf text (", dan ")
putpdf text ("bewarna"), bgcolor("yellow")
putpdf text ("."), linebreak

qui sum mpg
local sum : display %4.2f `r(sum)'
putpdf text ("Dan kamu juga bisa memasukkan hasil Stata di paragraph (mpg total = `sum')"), linebreak

// membuat dan memasukkan grafik
histogram rep78, frequency
graph export grafik.png, replace
putpdf paragraph, halign(center)
putpdf image grafik.png
putpdf text ("Histogram yang menampilkan frekuensi rep78 "), bold
putpdf text (" "), linebreak

putpdf paragraph, halign(right)
putpdf text ("Mari kita pindah ke halaman berikutnya")
putpdf pagebreak

// menambahkan hasil Stata
putpdf paragraph
putpdf text ("Menambahkan hasil dari regresi di Stata")
regress mpg price
putpdf table mytable = etable

putpdf paragraph, font(Cooper Black)
putpdf text ("Terima kasih, Enjoy your Stata")

putpdf save myreport.pdf, replace

Membuat dokumen Word

Hampir sama dengan membuat pdf, tetapi untuk word digunakan command putdocx. 

Dokumen word (*.docx) bisa dibuat dengan paragrah, tabel, hasil (output) dari Stata baik dalam paragraf, tabel maupun grafik.  

Berikut command yang diperlukan:

putdocx begin [ ,document_options]

->  untuk memulai membuat dokumen 

putdocx paragraph [, paragraph_options ] 

-> menambahkan paragraf ke dokumen

putdocx text ( text or exp ) [, text_option]

-> menambahkan text (tulisan)

putdocx image  filename [, image_option] 

-> menambahkan gambar

putdocx table tablename  

-> untuk menambahkan tabel

putdocx pagebreak 

-> untuk menambahkan pagebreak

putdocx save filename [,replace|append] 

-> untuk membuat dan menyimpan dokumen

putdocx append filename1 filename2 [filename 3[....]] [,saving(filename[,replace])]

-> untuk menggabungkan beberapa dokumen sekaligus

Contoh:

Pada bagian command atau bisa juga di buat do-files yangberisi:

sysuse auto, replace
putdocx begin

// membuat paragraf
putdocx paragraph
putdocx text ("Mencoba membuat putdocx "), bold
putdocx text ("  enter"), linebreak
putdocx text ("Bisa menambahkan tulisan sesuai kebutuhan. Bisa membuat tulisan ")
putdocx text ("miring, "), italic
putdocx text (" dicoret, "), strikeout
putdocx text ("digaris bawahi"), underline
putdocx text (", sub/super script")
putdocx text ("2 "), script(sub)
putdocx text (", dan ")
putdocx text ("bewarna"), shading("pink")
putdocx text ("."), linebreak

qui sum mpg
local sum : display %4.2f `r(sum)'
putdocx text ("Dan kamu juga bisa memasukkan hasil Stata di paragraph (mpg total = `sum')"), linebreak

// membuat dan memasukkan grafik
histogram rep78, frequency
graph export grafik.png, replace
putdocx paragraph, halign(center)
putdocx image grafik.png
putdocx text ("Histogram yang menampilkan frekuensi rep78 "), bold
putdocx text (" "), linebreak

putdocx paragraph, halign(right)
putdocx text ("Mari kita pindah ke halaman berikutnya")
putdocx pagebreak

// menambahkan hasil Stata
putdocx paragraph
putdocx text ("Menambahkan hasil dari regresi di Stata")
regress mpg price
putdocx table mytable = etable

putdocx paragraph, font(Cooper Black)
putdocx text ("Terima kasih, Enjoy your Stata")
putdocx save myWordreport.docx, replace

TechTip ini di adaptasi dari Stata